« Sauvegarde » : différence entre les versions

Version du 8 juin 2022 à 15:53

Pourquoi sauvegarder est-il si important ?

Sauvegarde ponctuelle

Fichiers / Utilitaires / Sauvegarde

Renseigner le chemin où sera enregistrer la sauvegarde dans Sauvegarder dans en haut à gauche.
Cliquer sur Marque tout pour prendre toutes les données.
En fonction de la périodicité, choisir journalière, mensuelle,annuelle ou bien encore Carte+. La sauvegarde annuelle sauvegarde plus de choses, les index et les programmes, ce que ne fait pas la sauvegarde quotidienne. La sauvegarde Carte+ est utilisée en cas d'assistance. Elle permet de faire une sauvegarde très légère en terme de poids capable de transiter par mail. Le support peut alors récupérer les données et analyser la problématique.
Une fois le type de sauvegarde choisie, Sauvegarder
Valider les messages de confirmation ( 2 ).

Sauvegarde externe

Avec une solution de sauvegarde dédiée

Les collectivités disposent désormais généralement de solution de sauvegarde externalisée, i.e les données sont sauvées sur un site distant. Dans ce cas, il faut paramétrer cette solution pour qu'elle comprenne les données Carte + (Typiquement C:/Carteplus/Fichiers).

FTP et tâche planifiée

Ce billet décrit comment, à l'aide d'une tâche planifiée Windows, on peut systématiser la sauvegarde des données Carte+

Prérequis

Avoir accès au serveur Carte+ et au mot de passe administrateur de la machine
Sur le ftp qui va accueillir les données, disposer d'un accès en écriture au chemin /07_Dossiers_clients/JolieVille/Sauvegarde

Installation

Créer un fichier SauvC+.bat, au même niveau que le dossier Fichiers de l'installation Carte +, dont le contenu est le suivant :

@Echo OFF

SET Client=%1
SET Nom=%Client%_%DATE:~6,4%%DATE:~3,2%%DATE:~0,2%

CD /D %~dp0

::Téléchargement des outils
IF EXIST "%~dp07za.exe" goto :dl2
powershell -Command "(New-Object System.Net.WebClient).DownloadFile('http://indywiki.fr/DADSU/7za.exe','%~dp07za.exe')"

:dl2
IF EXIST "%~dp0WinSCP.7z" goto :compression
powershell -Command "(New-Object System.Net.WebClient).DownloadFile('http://indywiki.fr/DADSU/WinSCP.7z','%~dp0WinSCP.7z')"


::Création de l'archive compressée
:compression
7za a -y %Nom%.7z -ssw ".\Fichiers\*" -x!*.ndx -mx9
7za e -y WinSCP.7z


::Initialisation des infos de connexion au FTP
for /f "tokens=*" %%A in (infos.txt) do (
   SET Hote=%%A
   goto endf_0
)
:endf_0

for /f "tokens=* skip=1" %%A in (infos.txt) do (
   SET login=%%A
   goto endf_1
)
:endf_1

for /f "tokens=* skip=2" %%A in (infos.txt) do (
   SET mdp=%%A
   goto endf_2
)
:endf_2

:: Installation du client FTP puis upload de l'archive ...
winscp.com /command^
    "open ftp://%login%:%mdp%@%Hote%/"^
    "option confirm off"^
    "cd 07_Dossiers_clients\%Client%\Sauvegarde"^
    "put %Nom%.7z"^
    "exit" 

::Purge des outils
del /q *.exe winscp.* %Nom%.7z infos.txt
goto :EOF

::Fin de la partie
:EOF